erlang list manipulation

I have a list of tuples:

L = [{1, [a, b, c]}, {2, [d, e, f]}, {3, [[h, i, j], [k, l, m]]}]开发者_运维问答

this is what I have

lists:map(fun({_, B}-> B end, L).

the output is

[[a, b, c], [d, e, f], [[h, i, j], [k, l, m]]]

what I want is:

[[a, b, c], [d, e, f], [h, i, j], [k, l, m]]

it seems a pretty easy problem, but I can't figure out how to do it. Please help!

---

Let's see...

1> L = [{1, [a, b, c]}, {2, [d, e, f]}, {3, [[h, i, j], [k, l, m]]}].
[{1,[a,b,c]},{2,[d,e,f]},{3,[[h,i,j],[k,l,m]]}]

Trivial and straightforward, but not tail-recursive:

2> lists:foldr(fun ({_,[X|_]=E},A) when is_list(X) -> lists:append(A,E);
                   ({_,E},A) -> [E|A] end,
                [], L).
[[a,b,c],[d,e,f],[h,i,j],[k,l,m]]

Not being tail-recursive is not very nice, though, but...

3> lists:reverse(lists:foldl(fun ({_,[X|_]=E},A) when is_list(X) ->
                                     lists:reverse(E,A);
                                 ({_,E},A) -> [E|A] end,
                             [], L)).
[[a,b,c],[d,e,f],[h,i,j],[k,l,m]]

...the tail-recursive version also works (thanks to Zed for pointing out lists:reverse/2).

---

For your specific example case, you can define the following function:

group3([], Acc) ->
     Acc;
group3([A,B,C|Tl], Acc) ->
    group3(Tl, [[A,B,C]] ++ Acc).

group3(L) ->
    lists:reverse(group3(L, [])).

and invoke it like this:

group3(lists:flatten(lists:map(fun({_, B}) -> B end, L))).

Hopefully that's enough to give you a general strategy.

---

-module(z).
-export([do/1]).

do([{_,[X|_] = L}|Tl]) when is_list(X) -> L ++ do(Tl);
do([{_, L}       |Tl])                 -> [L|do(Tl)];
do([])                                 -> [].

test:

1> z:do(L).
[[a,b,c],[d,e,f],[h,i,j],[k,l,m]]