vim can't open syntax.vim

In my .vimrc I have the following snippet:

if has('autocmd')
    filetype plugin indent on
    syntax on

but when I start vim it sh开发者_开发技巧ows the following error:

Can't open file /usr/share/vim/syntax/syntax.vim

error seems to have occurred on syntax on line in .vimrc.

I do not have syntax.vim in path /usr/share/vim/syntax though I have others like clojure.vim cpp.vim java.vim etc...

I searched but can't seem to find the default syntax.vim if it comes with default version of vim.

I've been stuck with this for a while and would like some help.

---

I use Arch and build vim from the AUR using the vim-git PKGBUILD. For me, it was the case of using vim-git, but vim-runtime from the official repos, not vim-runtime-git from the AUR.

Switching to vim-runtime-git solved this issue for me and provided the syntax file (and colours, and...).

---

It should be there so there may be other files missing. I would suggest you re-install!.

For a QDF here is what the syntax.vim file should look like this:-

" Vim syntax support file
" Maintainer:   Bram Moolenaar <Bram@vim.org>
" Last Change:  2001 Sep 04

" This file is used for ":syntax on".
" It installs the autocommands and starts highlighting for all buffers.

if !has("syntax")
  finish
endif

" If Syntax highlighting appears to be on already, turn it off first, so that
" any leftovers are cleared.
if exists("syntax_on") || exists("syntax_manual")
  so <sfile>:p:h/nosyntax.vim
endif

" Load the Syntax autocommands and set the default methods for highlighting.
runtime syntax/synload.vim

" Load the FileType autocommands if not done yet.
if exists("did_load_filetypes")
  let s:did_ft = 1
else
  filetype on
  let s:did_ft = 0
endif

" Set up the connection between FileType and Syntax autocommands.
" This makes the syntax automatically set when the file type is detected.
augroup syntaxset
  au! FileType *    exe "set syntax=" . expand("<amatch>")
augroup END


" Execute the syntax autocommands for the each buffer.
" If the filetype wasn't detected yet, do that now.
" Always do the syntaxset autocommands, for buffers where the 'filetype'
" already was set manually (e.g., help buffers).
doautoall syntaxset FileType
if !s:did_ft
  doautoall filetypedetect BufRead
endif

---

I had this problem as well after upgrading to 7.3 (I'm using cygwin). Check whether running "vi" instead of "vim" has the same problem. I found that vim was actually the old 7.2 executable, but the syntax files were in the location expected by 7.3; vi was the correct 7.3 executable.

---

I have been using compiled vim from source without explicitly installing it on my system (due to missing sudo privileges).

I was able to solve the issue by adding the following line to my .bashrc:

export VIMRUNTIME=<path to cloned vim repo>/runtime

Thus: Pointing this env variable to the runtime director in the git tree, makes vim find the needed file(s).