How can I access directory-local variables in my major mode hooks?

I have defined a .dir-locals.el file with the following content:

((python-mode . ((cr/virtualenv-name . "saas"))))

In my .emacs I have the following function to retrieve this value an开发者_StackOverflow中文版d provide a virtualenv path:

(defun cr/virtualenv ()
  (cond (cr/virtualenv-name (format "%s/%s" virtualenv-base cr/virtualenv-name))
        ((getenv "EMACS_VIRTUAL_ENV") (getenv "EMACS_VIRTUAL_ENV"))
        (t "~/.emacs.d/python")))

Finally, in my python-mode-hook list, I have this hook function:

(add-hook 'python-mode-hook 'cr/python-mode-shell-setup)

(defun cr/python-mode-shell-setup ()
  (message "virtualenv-name is %s" cr/virtualenv-name)
  (let ((python-base (cr/virtualenv)))
    (cond ((and (fboundp 'ipython-shell-hook) (file-executable-p (concat python-base "/bin/ipython")))
           (setq python-python-command (concat python-base "/bin/ipython"))
           (setq py-python-command (concat python-base "/bin/ipython"))
           (setq py-python-command-args '( "-colors" "NoColor")))
          (t
           (setq python-python-command (concat python-base "/bin/python"))
           (setq py-python-command (concat python-base "/bin/python"))
           (setq py-python-command-args nil)))))

When I open a new python file, the message logged by cr/python-mode-shell-setup indicates that cr/virtualenv-name is nil. However, when I C-h v the name, I get "saas" instead.

Obviously there's a load order issue here; is there a way to have my mode hook statements respond to directory-local variables?

---

This happens because normal-mode calls (set-auto-mode) and (hack-local-variables) in that order.

However hack-local-variables-hook is run after the local variables have been processed, which enables some solutions:

1. The first is to make Emacs run a new "local variables hook" for each major mode:

   (add-hook 'hack-local-variables-hook 'run-local-vars-mode-hook)
   (defun run-local-vars-mode-hook ()
     "Run a hook for the major-mode after the local variables have been processed."
     (run-hooks (intern (concat (symbol-name major-mode) "-local-vars-hook"))))
   
   (add-hook 'python-mode-local-vars-hook 'cr/python-mode-shell-setup)
   

   (Your original function can be used unmodified, with that approach.)

2. A second option is to utilise the optional LOCAL argument to add-hook that makes the specified function buffer-local. With this approach you could write your hook as follows:

   (add-hook 'python-mode-hook 'cr/python-mode-shell-setup)
   
   (defun cr/python-mode-shell-setup ()
     (add-hook 'hack-local-variables-hook
               (lambda () (message "virtualenv-name is %s" cr/virtualenv-name)
                 (let ((python-base (cr/virtualenv)))
                   (cond ((and (fboundp 'ipython-shell-hook) (file-executable-p (concat python-base "/bin/ipython")))
                          (setq python-python-command (concat python-base "/bin/ipython"))
                          (setq py-python-command (concat python-base "/bin/ipython"))
                          (setq py-python-command-args '( "-colors" "NoColor")))
                         (t
                          (setq python-python-command (concat python-base "/bin/python"))
                          (setq py-python-command (concat python-base "/bin/python"))
                          (setq py-python-command-args nil)))))
               nil t)) ; buffer-local hack-local-variables-hook
   

   i.e. python-mode-hook runs first and registers the anonymous function with hack-local-variables-hook for the current buffer only; and that function is then called after the local variables have been processed.

3. Lindydancer's comment prompts a third approach. It's not nearly as clean as the other two, but proved interesting regardless. I didn't like the idea of causing (hack-local-variables) to be called twice, but I see that if you set the local-enable-local-variables buffer-locally, it prevents (hack-local-variables) from doing anything, so you could do this:

   (defun cr/python-mode-shell-setup ()
     (report-errors "File local-variables error: %s"
       (hack-local-variables)))
     (set (make-local-variable 'local-enable-local-variables) nil)
     (let ((python-base (cr/virtualenv)))
       ...))
   

   Obviously that modifies the normal sequence of execution a little, so side effects may be possible. I was worried that if the same major mode is set by a local variable comment in the file, this might cause infinite recursion, but that doesn't actually appear to be a problem.

   Local variable header comments (e.g. -*- mode: foo -*-) are handled by (set-auto-mode), so those are fine; but a mode: foo Local Variables: comment seems like it would be an issue as it is handled by (hack-local-variables), and so if the mode is set that way I thought it would cause recursion.

   In practice I was able to trigger the problem by using a simple function as a 'mode' which did nothing more than try to run its hooks; however testing with a 'proper' mode did not exhibit the problem, so it's probably safe in reality. I didn't look into this further (as the other two solutions are much cleaner than this), but I would guess the delayed mode hooks mechanism probably explains it?